Ascension/velocity/build.gradle

apply from: rootProject.file('buildscript/standalone.gradle')
apply plugin: 'net.kyori.blossom'

shadowJar {
    archiveBaseName = 'DiscordSRV-Velocity'

    // Relocations in buildscript/relocations.gradle
}

repositories {
    exclusiveContent {
        forRepository {
            maven { url 'https://nexus.velocitypowered.com/repository/maven-public/' }
        }
        filter {
            includeGroup 'com.velocitypowered'
        }
    }
}

var velocityVersion = '3.0.0'
dependencies {
    // API
    annotationProcessor project(':api')
    implementation project(':common:common-api')

    // Common
    implementation project(':common:common-proxy')

    // Platform
    annotationProcessor 'com.velocitypowered:velocity-api:' + velocityVersion
    compileOnly 'com.velocitypowered:velocity-api:' + velocityVersion

    // DependencyDownload
    implementation 'dev.vankka.minecraftdependencydownload:velocity:' + rootProject.mddVersion
}

jar {
    dependsOn blossomSourceReplacementJava
}

blossom {
    var mainClass = 'src/main/java/com/discordsrv/velocity/DiscordSRVVelocityBootstrap.java'
    replaceToken('@VERSION@', project.version, mainClass)
}