Ascension/bungee/build.gradle

shadowJar {
    archiveFileName = 'bungee.jarinjar'

    configure {
        [
                'net.kyori'
        ].each {
            relocate it, 'com.discordsrv.dependencies.' + it
        }
    }
    // More relocations in buildscript/relocations.gradle
}

apply from: rootProject.file('buildscript/runtime.gradle')

allprojects {
    repositories {
        exclusiveContent {
            forRepository {
                maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
            }
            filter {
                includeGroup 'net.md-5'
            }
        }
    }

    dependencies {
        // Platform
        compileOnly(libs.bungee)
    }
}

dependencies {
    // API
    annotationProcessor project(':api')

    // Common
    implementation project(':common')
    implementation project(':common:common-templates')

    // DependencyDownload
    implementation(libs.mcdependencydownload.bungee.bootstrap)

    // Adventure
    runtimeDownloadApi(libs.adventure.platform.bungee)
    runtimeDownloadApi(libs.adventure.serializer.bungee)
}