repositories {        
	maven {
		url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'

		content {
			includeGroup 'org.spigotmc'
		}
	}
}

dependencies {
    shadow "org.spigotmc:spigot-api:1.13-R0.1-SNAPSHOT"
    
    implementation group: 'org.bstats', name: 'bstats-bukkit-lite', version: '1.5'

	implementation (project(':BlueMapCommon')) {
    	//exclude dependencies provided by bukkit
    	exclude group: 'com.google.guava', module: 'guava'
		exclude group: 'com.google.code.gson', module: 'gson'
    }
}

build.dependsOn shadowJar {
	destinationDirectory = file '../../build/release'
	archiveFileName.set("BlueMap-${archiveVersion.get()}-spigot.jar")
	
	//relocate 'com.flowpowered.math', 'de.bluecolored.shadow.flowpowered.math' //DON'T relocate this, because the API depends on it
	relocate 'com.typesafe.config', 'de.bluecolored.shadow.typesafe.config'
	relocate 'net.querz.nbt', 'de.bluecolored.shadow.querz.nbt'
	relocate 'org.spongepowered.configurate', 'de.bluecolored.shadow.configurate'
	relocate 'org.apache.commons.io', 'de.bluecolored.shadow.apache.commons.io'
	relocate 'org.apache.commons.lang3', 'de.bluecolored.shadow.apache.commons.lang3'
	relocate 'org.bstats.bukkit', 'de.bluecolored.shadow.bstats.bukkit'
	relocate 'com.mojang.brigadier', 'de.bluecolored.shadow.mojang.brigadier'
	relocate 'com.github.benmanes.caffeine', 'de.bluecolored.shadow.benmanes.caffeine'
	relocate 'com.google.errorprone', 'de.bluecolored.shadow.google.errorprone'
	relocate 'org.aopalliance', 'de.bluecolored.shadow.aopalliance'
	relocate 'javax.inject', 'de.bluecolored.shadow.javax.inject'
	relocate 'com.google.inject', 'de.bluecolored.shadow.google.inject'
	relocate 'org.checkerframework', 'de.bluecolored.shadow.checkerframework'
	relocate 'org.codehaus', 'de.bluecolored.shadow.codehaus'
	relocate 'io.leangen.geantyref', 'de.bluecolored.shadow.geantyref'
}

processResources {
	from(sourceSets.main.resources.srcDirs) {
		include 'plugin.yml'
		duplicatesStrategy = DuplicatesStrategy.WARN
		
		expand (
			version: project.version
		)
	}
}