buildscript {
    repositories {
        mavenCentral()
        maven { url = "https://oss.sonatype.org/content/repositories/snapshots/" }
        jcenter()
    }
	dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
        classpath 'org.ajoberstar:grgit:1.7.0'
    }

}

apply plugin: 'java'
clean { delete "target" }

group = 'com.boydti.fawe'

def revision = ""
def buildNumber = ""
final def date = new Date().format("yy.MM.dd")
ext {
    git = org.ajoberstar.grgit.Grgit.open(file(".git"))
    revision = "-${git.head().abbreviatedId}"
    parents = git.head().parentIds;
    index = -44;  // Offset to mach CI
    for (;parents != null && !parents.isEmpty();index++) {
        commit = git.getResolve().toCommit(parents.get(0));
        parents = commit.getParentIds();
    }
    buildNumber = "-${index}"
}

version = date + revision + buildNumber
description = """FastAsyncWorldEdit"""

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'eclipse'
    apply plugin: 'idea'

    sourceCompatibility = 1.7
    targetCompatibility = 1.7

    dependencies {
        compile(group: 'com.sk89q.worldedit', name: 'worldedit-core', version:'6.1.3-SNAPSHOT') {
            exclude(module: 'bukkit-classloader-check')
        }
        compile 'com.sk89q:worldguard:6.0.0-SNAPSHOT'
        compile 'com.plotsquared:PlotSquared:3.4.1-SNAPSHOT'
        compile 'org.primesoft:BlocksHub:2.0'
    }

    repositories {
        mavenCentral()
        maven {url "http://empcraft.com/maven2"}
        maven {url "http://repo.mcstats.org/content/repositories/public"}
        maven {url "https://hub.spigotmc.org/nexus/content/groups/public/"}
        maven {url "http://maven.sk89q.com/repo/"}
        maven {url "http://nexus.hc.to/content/repositories/pub_releases"}
        maven {url "http://repo.maven.apache.org/maven2"}
        maven {url "http://ci.frostcast.net/plugin/repository/everything"}
        maven {url "http://maven.sk89q.com/artifactory/repo/"}
        maven {url "http://repo.spongepowered.org/maven"}
    }
}