LuckPerms/standalone/build.gradle

plugins {
    alias(libs.plugins.shadow)
    id("jacoco")
    id("jacoco-report-aggregation")
}

sourceCompatibility = 17
targetCompatibility = 17

test {
    useJUnitPlatform {
        if (!project.hasProperty('dockerTests')) {
            excludeTags 'docker'
        }
    }
    systemProperty('net.kyori.ansi.colorLevel', 'indexed16')
}

jacocoTestReport {
    dependsOn test
}

dependencies {
    implementation project(':common')
    compileOnly project(':common:loader-utils')
    compileOnly project(':standalone:app')

    compileOnly 'org.spongepowered:configurate-yaml:3.7.2'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.1'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.9.1'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.9.1'
    testImplementation "org.testcontainers:junit-jupiter:1.18.3"
    testImplementation 'org.mockito:mockito-core:4.11.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:4.11.0'
    testImplementation 'org.awaitility:awaitility:4.2.0'

    testImplementation 'com.zaxxer:HikariCP:4.0.3'
    testImplementation 'redis.clients:jedis:4.4.3'
    testImplementation 'io.nats:jnats:2.16.4'
    testImplementation 'com.rabbitmq:amqp-client:5.12.0'
    testImplementation 'org.postgresql:postgresql:42.6.0'
    testImplementation 'com.h2database:h2:2.1.214'
    testImplementation 'org.xerial:sqlite-jdbc:3.42.0.0'
    testImplementation 'mysql:mysql-connector-java:8.0.23'
    testImplementation 'org.mariadb.jdbc:mariadb-java-client:3.1.3'
    testImplementation 'org.mongodb:mongodb-driver-legacy:4.5.0'
    testImplementation 'me.lucko.configurate:configurate-toml:3.7'
    testImplementation 'org.spongepowered:configurate-hocon:3.7.2'
    testImplementation 'org.yaml:snakeyaml:1.28'

    testImplementation project(':standalone:app')
    testImplementation project(':common:loader-utils')
}

shadowJar {
    archiveFileName = 'luckperms-standalone.jarinjar'

    dependencies {
        include(dependency('me.lucko.luckperms:.*'))
    }

    relocate 'net.kyori.event', 'me.lucko.luckperms.lib.eventbus'
    relocate 'com.github.benmanes.caffeine', 'me.lucko.luckperms.lib.caffeine'
    relocate 'okio', 'me.lucko.luckperms.lib.okio'
    relocate 'okhttp3', 'me.lucko.luckperms.lib.okhttp3'
    relocate 'net.bytebuddy', 'me.lucko.luckperms.lib.bytebuddy'
    relocate 'me.lucko.commodore', 'me.lucko.luckperms.lib.commodore'
    relocate 'org.mariadb.jdbc', 'me.lucko.luckperms.lib.mariadb'
    relocate 'com.mysql', 'me.lucko.luckperms.lib.mysql'
    relocate 'org.postgresql', 'me.lucko.luckperms.lib.postgresql'
    relocate 'com.zaxxer.hikari', 'me.lucko.luckperms.lib.hikari'
    relocate 'com.mongodb', 'me.lucko.luckperms.lib.mongodb'
    relocate 'org.bson', 'me.lucko.luckperms.lib.bson'
    relocate 'redis.clients.jedis', 'me.lucko.luckperms.lib.jedis'
    relocate 'io.nats.client', 'me.lucko.luckperms.lib.nats'
    relocate 'com.rabbitmq', 'me.lucko.luckperms.lib.rabbitmq'
    relocate 'org.apache.commons.pool2', 'me.lucko.luckperms.lib.commonspool2'
    relocate 'ninja.leaping.configurate', 'me.lucko.luckperms.lib.configurate'
    relocate 'org.yaml.snakeyaml', 'me.lucko.luckperms.lib.yaml'
}

artifacts {
    archives shadowJar
}