LuckPerms/forge/loader/build.gradle

plugins {
    alias(libs.plugins.shadow)
    alias(libs.plugins.forgegradle)
    id("java-library")
}

sourceCompatibility = 17
targetCompatibility = 21

minecraft {
    mappings channel: 'official', version: minecraftVersion
}

dependencies {
    minecraft "net.minecraftforge:forge:${minecraftVersion}-${forgeVersion}"
    implementation project(':api')
    implementation project(':common:loader-utils')
    implementation project(':forge:forge-api')
}

build {
    dependsOn(":forge:build")
    dependsOn(":forge:forge-api:build")
}

jar {
    manifest {
        attributes(
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Implementation-Title': 'LuckPerms',
                'Implementation-Vendor': 'LuckPerms',
                'Implementation-Version': project.ext.fullVersion,
                'Specification-Title': 'luckperms',
                'Specification-Vendor': 'LuckPerms',
                'Specification-Version': '1'
        )
    }
}

processResources {
    filesMatching('META-INF/mods.toml') {
        expand 'version': project.ext.fullVersion
    }
}

shadowJar {
    archiveFileName = "LuckPerms-Forge-${project.ext.fullVersion}.jar"

    from {
        project(':forge').tasks.shadowJar.archiveFile
    }

    dependencies {
        include(dependency('net.luckperms:.*'))
        include(dependency('me.lucko.luckperms:.*'))
    }
}

artifacts {
    archives shadowJar
}