PlotSquared/Bukkit/build.gradle

repositories {
    maven {url "https://hub.spigotmc.org/nexus/content/groups/public/"}
    maven { url = "https://oss.sonatype.org/content/repositories/snapshots/"}
    maven {url "http://nexus.theyeticave.net/content/repositories/pub_releases"}
}

dependencies {
    compile project(':Core')
    compile 'org.spigotmc:spigot-api:1.10.2-R0.1-SNAPSHOT'
    compile 'net.milkbowl.vault:VaultAPI:1.6'
}

sourceCompatibility = 1.7
targetCompatibility = 1.7

processResources {
    from('src/main/resources') {
        include 'plugin.yml'
        expand(
            name: project.parent.name,
            version: project.parent.version
        )
    }
}
// We only want the shadow jar produced
jar.enabled = false

shadowJar {
    dependencies {
        include(dependency(':Core'))
    }
    relocate('org.mcstats', 'com.plotsquared.stats')
    archiveName = "${parent.name}-${project.name}-${parent.version}.jar"
    destinationDir = file '../target'
}

shadowJar.doLast {
    task ->
    ant.checksum file: task.archivePath
}

build.dependsOn(shadowJar);