buildscript {
    repositories {
        jcenter()
        mavenLocal()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {url = "http://repo.minecrell.net/releases"}
    }
    dependencies {
        classpath 'net.minecrell:VanillaGradle:2.0.3_1'
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT'
    }
}

apply plugin: 'net.minecrell.vanilla.server.library'
apply plugin: 'com.github.johnrengelman.shadow'

dependencies {
    compile project(':Core')
    compile 'org.spongepowered:spongeapi:5.0.0-SNAPSHOT'
    //compile 'org.mcstats.sponge:metrics:R8-SNAPSHOT'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    maven {
        name = 'forge'
        url = 'http://files.minecraftforge.net/maven'
    }
    maven {
        name = "Sponge"
        url = "https://repo.spongepowered.org/maven"
    }
    maven {
        name = "Sponge Metrics"
        url = "http://repo.mcstats.org/content/repositories/releases/"
    }
}
minecraft {
    version = "1.9.4"
    mappings = "snapshot_20160530"
    runDir = 'run'
}

project.archivesBaseName = "${project.archivesBaseName}-mc${minecraft.version}"

processResources {
    from(sourceSets.main.resources.srcDirs) {
        expand 'version': project.version,
                'mcVersion': project.minecraft.version
    }
}
shadowJar {
    dependencies {
        include(dependency(':Core'))
        //include(dependency('org.mcstats.sponge:metrics:R8-SNAPSHOT'))
    }
    //relocate 'org.mcstats', 'com.plotsquared.stats'
    archiveName = "${parent.name}-${project.name}-${parent.version}.jar"
    destinationDir = file '../target'
}
shadowJar.doLast {
    task ->
        ant.checksum file: task.archivePath
}

reobf {
    shadowJar {
        mappingType = 'SEARGE'
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
}

build.dependsOn(shadowJar)