Upstream/ViaFabric
1
0
Fork 0
mirror of https://github.com/ViaVersion/ViaFabric.git synced 2025-01-17 20:31:25 +01:00
Code Issues Packages Projects Releases Wiki Activity

19w12a

Browse Source
This commit is contained in:
creeper123123321 2019-03-20 19:39:34 -03:00
parent 1fee4cc779
commit 00a10647af
No known key found for this signature in database
GPG Key ID: 0AC57D54786721D1
5 changed files with 93 additions and 87 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

82
build.gradle
View File

@ -1,82 +0,0 @@
import org.apache.tools.ant.filters.ReplaceTokens
plugins {
id 'java'
id 'net.minecrell.licenser' version '0.4.1'
id 'fabric-loom' version '0.2.0-SNAPSHOT'
id 'com.palantir.git-version' version '0.12.0-rc2'
}
group 'com.github.creeper123123321.viafabric'
version '0.1.0-SNAPSHOT+' + gitVersion()
archivesBaseName = 'ViaFabric'
description = 'Client-side and server-side ViaVersion for Fabric'
sourceCompatibility = 1.8
targetCompatibility = 1.8
repositories {
mavenLocal()
mavenCentral()
jcenter()
maven { url 'https://repo.viaversion.com/' }
maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
maven { url 'https://maven.fabricmc.net/' }
}
processResources {
filter ReplaceTokens, tokens: [
"version": project.property('version'),
"description": project.property('description')
]
}
configurations {
shade
compile.extendsFrom shade
}
dependencies {
// transitive = false, viabackwards-core because Guava is conflicting on runClient
shade("us.myles:viaversion:2.0.0-19w12a") { transitive = false }
shade("de.gerrygames:viarewind-core:1.4.0") { transitive = false }
shade("nl.matsv:viabackwards-core:3.0.0-19w11b") { transitive = false }
compileOnly 'com.google.code.findbugs:jsr305:3.0.2'
minecraft "com.mojang:minecraft:19w12a"
mappings "net.fabricmc:yarn:19w12a.1"
modCompile "net.fabricmc:fabric-loader:0.3.7.109"
modCompile "net.fabricmc:fabric:0.2.3.111"
}
jar {
configurations.shade.each { dep ->
from(project.zipTree(dep)) {
//exclude 'META-INF', 'META-INF/**'
exclude 'us/myles/ViaVersion/BungeePlugin.class'
exclude 'us/myles/ViaVersion/SpongePlugin.class'
exclude 'us/myles/ViaVersion/VelocityPlugin.class'
exclude 'us/myles/ViaVersion/ViaVersionPlugin.class'
exclude 'us/myles/ViaVersion/bukkit/**'
exclude 'us/myles/ViaVersion/velocity/**'
exclude 'us/viaversion/libs/javassist/**'
exclude 'mcmod.info'
exclude 'plugin.yml'
exclude 'bungee.yml'
exclude 'velocity-plugin.json'
}
}
}
minecraft {
}
// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
classifier = 'sources'
from sourceSets.main.allSource
}

88
build.gradle.kts Normal file
View File

@ -0,0 +1,88 @@
import org.apache.tools.ant.filters.ReplaceTokens
import java.net.URI
plugins {
id("java")
id("net.minecrell.licenser") version "0.4.1"
id("fabric-loom") version "0.2.0-SNAPSHOT"
id("com.palantir.git-version") version "0.12.0-rc2"
}
group = "com.github.creeper123123321.viafabric"
val gitVersion: groovy.lang.Closure<Any> by extra
version = "0.1.0-SNAPSHOT+" + gitVersion()
extra.set("archivesBaseName", "ViaFabric")
description = "Client-side and server-side ViaVersion for Fabric"
java {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
extra.set("sourceCompatibility", 1.8)
extra.set("targetCompatibility", 1.8)
repositories {
mavenLocal()
mavenCentral()
jcenter()
maven { url = URI.create("https://repo.viaversion.com/") }
maven { url = URI.create("https://oss.sonatype.org/content/repositories/snapshots") }
maven { url = URI.create("https://maven.fabricmc.net/") }
}
tasks.getByName<ProcessResources>("processResources").apply {
filter<ReplaceTokens>("tokens" to mapOf(
"version" to project.property("version"),
"description" to project.property("description")
))
}
val shade by configurations.creating
configurations.getByName("compile").extendsFrom(shade)
dependencies {
// transitive = false, viabackwards-core because Guava is conflicting on runClient
shade("us.myles:viaversion:2.0.0-19w12a") { isTransitive = false }
shade("de.gerrygames:viarewind-core:1.4.0") { isTransitive = false }
shade("nl.matsv:viabackwards-core:3.0.0-19w11b") { isTransitive = false }
compileOnly("com.google.code.findbugs:jsr305:3.0.2")
minecraft("com.mojang:minecraft:19w12a")
mappings("net.fabricmc:yarn:19w12a.2")
modCompile("net.fabricmc:fabric-loader:0.3.7.109")
modCompile("net.fabricmc:fabric:0.2.4.113")
}
tasks.named<Jar>("jar") {
shade.forEach { dep ->
from(project.zipTree(dep)) {
exclude("us/myles/ViaVersion/BungeePlugin.class")
exclude("us/myles/ViaVersion/SpongePlugin.class")
exclude("us/myles/ViaVersion/VelocityPlugin.class")
exclude("us/myles/ViaVersion/ViaVersionPlugin.class")
// exclude("us/myles/ViaVersion/sponge/**") needed for viabackwards version check
exclude("us/myles/ViaVersion/bukkit/**")
exclude("us/myles/ViaVersion/bungee/**")
exclude("us/viaversion/libs/javassist/**")
exclude("mcmod.info")
exclude("plugin.yml")
exclude("bungee.yml")
exclude("velocity-plugin.json")
}
}
}
minecraft {
}
// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
tasks.register<Jar>("sourcesJar") {
dependsOn(tasks.getByName("classes"))
classifier = "sources"
from(sourceSets.getByName("main").allSource)
}

4
src/main/java/com/github/creeper123123321/viafabric/mixin/client/MixinMultiplayerScreen.java
View File

@ -92,9 +92,9 @@ public abstract class MixinMultiplayerScreen extends Screen {
this.listeners.add(protocolVersion);
}
@Inject(method = "draw", at = @At(value = "INVOKE", target = "Lnet/minecraft/client/gui/Screen;draw(IIF)V"))
@Inject(method = "render", at = @At(value = "INVOKE", target = "Lnet/minecraft/client/gui/Screen;draw(IIF)V"), remap = false)
private void onDraw(int int_1, int int_2, float float_1, CallbackInfo ci) {
protocolVersion.draw(int_1, int_2, float_1);
protocolVersion.render(int_1, int_2, float_1);
}
@Inject(method = "update", at = @At("TAIL"))

4
src/main/java/com/github/creeper123123321/viafabric/platform/VRLoader.java
View File

@ -27,14 +27,14 @@ package com.github.creeper123123321.viafabric.platform;
import com.github.creeper123123321.viafabric.providers.VRVersionProvider;
import us.myles.ViaVersion.api.Via;
import us.myles.ViaVersion.api.platform.ViaPlatformLoader;
import us.myles.ViaVersion.bungee.providers.BungeeMovementTransmitter;
import us.myles.ViaVersion.protocols.base.VersionProvider;
import us.myles.ViaVersion.protocols.protocol1_9to1_8.providers.MovementTransmitterProvider;
import us.myles.ViaVersion.velocity.providers.VelocityMovementTransmitter;
public class VRLoader implements ViaPlatformLoader {
@Override
public void load() {
Via.getManager().getProviders().use(MovementTransmitterProvider.class, new BungeeMovementTransmitter());
Via.getManager().getProviders().use(MovementTransmitterProvider.class, new VelocityMovementTransmitter());
Via.getManager().getProviders().use(VersionProvider.class, new VRVersionProvider());
}

2
src/main/java/com/github/creeper123123321/viafabric/platform/VRPlatform.java
View File

@ -52,8 +52,8 @@ import us.myles.ViaVersion.api.type.Type;
import us.myles.ViaVersion.dump.PluginInfo;
import us.myles.ViaVersion.exception.CancelException;
import us.myles.ViaVersion.protocols.protocol1_13to1_12_2.ChatRewriter;
import us.myles.ViaVersion.sponge.VersionInfo;
import us.myles.ViaVersion.util.GsonUtil;
import us.myles.ViaVersion.velocity.VersionInfo;
import us.myles.viaversion.libs.gson.JsonObject;
import javax.annotation.Nullable;