ViaForge/build.gradle

plugins {
    id "java"
    id "com.github.johnrengelman.shadow" version "7.0.0"
}

subprojects {
    apply plugin: "com.github.johnrengelman.shadow"

    archivesBaseName = "ViaForge-" + project.maven_name
    version = maven_version + project.mc_version
    group = maven_group

    configurations {
        library
        implementation.extendsFrom(library)
    }

    repositories {
        maven {
            url = "https://repo.spongepowered.org/repository/maven-public"
        }
        maven {
            url = "https://repo.viaversion.com"
        }
    }

    dependencies {
        library "com.viaversion:viaversion:${project.viaversion_version}"
        library "com.viaversion:viabackwards:${project.viabackwards_version}"
        library "com.viaversion:viarewind-universal:${project.viarewind_version}"
        library "org.yaml:snakeyaml:${project.snake_yml_version}"

        library "net.raphimc:ViaLoader:${project.vialoader_version}"
    }

    shadowJar {
        archiveFileName = jar.archiveFileName
        compileJava.options.encoding = "UTF-8"
        exclude "native-binaries/*"

        configurations = [project.configurations.compileClasspath]
    }

    jar.dependsOn("shadowJar")
}