ViaLegacy/build.gradle

plugins {
    id "java-library"
    id "maven-publish"
}

java.toolchain.languageVersion = JavaLanguageVersion.of(8)
compileJava.options.encoding = "UTF-8"

group = project.maven_group
archivesBaseName = project.maven_name
version = project.maven_version

repositories {
    mavenCentral()
    maven {
        name = "Lenni0451"
        url "https://maven.lenni0451.net/releases"
    }
    maven {
        name = "ViaVersion"
        url "https://repo.viaversion.com"
    }
}

dependencies {
    compileOnly "com.viaversion:viaversion:4.5.2-SNAPSHOT"
    compileOnly("com.viaversion:viabackwards-common:4.5.2-SNAPSHOT") {
        exclude group: "com.viaversion", module: "viaversion"
    }
    compileOnly "org.yaml:snakeyaml:1.33"
    //api "net.lenni0451.mcstructs:all:1.4.0" // Not yet used
}

java {
    withSourcesJar()
    withJavadocJar()
}

javadoc {
    failOnError = false
}

publishing {
    repositories {
        maven {
            name = "reposilite"
            url = "https://maven.lenni0451.net/releases"
            credentials(PasswordCredentials)
            authentication {
                basic(BasicAuthentication)
            }
        }
    }
    publications {
        maven(MavenPublication) {
            groupId = project.maven_group
            artifactId = project.maven_name
            version = project.maven_version

            from components.java
        }
    }
}