mirror of
https://github.com/bitwarden/server.git
synced 2024-11-26 12:55:17 +01:00
d965166a37
* [AC-2084] Add documentation to existing collection repository getters * [AC-2084] Add new CollectionAdminDetails model * [AC-2084] Add SQL and migration scripts * [AC-2084] Introduce new repository methods to include permission details for collections * [AC-2084] Add EF repository methods and integration tests * [AC-2084] Update CollectionsController and response models * [AC-2084] Fix failing SqlServer test * [AC-2084] Clean up admin endpoint response models - vNext endpoints should now always return CollectionDetailsResponse models - Update constructors in CollectionDetailsResponseModel to be more explicit and add named static constructors for additional clarity * [AC-2084] Fix failing tests * [AC-2084] Fix potential provider/member bug * [AC-2084] Fix broken collections controller * [AC-2084] Cleanup collection response model types and constructors * [AC-2084] Remove redundant authorization check * [AC-2084] Cleanup ambiguous model name * [AC-2084] Add GroupBy clause to sprocs * [AC-2084] Add GroupBy logic to EF repository * [AC-2084] Update collection repository tests * [AC-2084] Update migration script date * Update migration script date --------- Co-authored-by: Thomas Rittson <31796059+eliykat@users.noreply.github.com> Co-authored-by: kejaeger <138028972+kejaeger@users.noreply.github.com>
127 lines
3.3 KiB
Transact-SQL
127 lines
3.3 KiB
Transact-SQL
CREATE OR ALTER PROCEDURE [dbo].[Collection_ReadByIdWithPermissions]
|
|
@CollectionId UNIQUEIDENTIFIER,
|
|
@UserId UNIQUEIDENTIFIER,
|
|
@IncludeAccessRelationships BIT
|
|
AS
|
|
BEGIN
|
|
SET NOCOUNT ON
|
|
|
|
SELECT
|
|
C.*,
|
|
MIN(CASE
|
|
WHEN
|
|
COALESCE(CU.[ReadOnly], CG.[ReadOnly], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [ReadOnly],
|
|
MIN (CASE
|
|
WHEN
|
|
COALESCE(CU.[HidePasswords], CG.[HidePasswords], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [HidePasswords],
|
|
MAX(CASE
|
|
WHEN
|
|
COALESCE(CU.[Manage], CG.[Manage], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [Manage],
|
|
MAX(CASE
|
|
WHEN CU.[CollectionId] IS NULL AND CG.[CollectionId] IS NULL
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [Assigned]
|
|
FROM
|
|
[dbo].[CollectionView] C
|
|
LEFT JOIN
|
|
[dbo].[OrganizationUser] OU ON C.[OrganizationId] = OU.[OrganizationId] AND OU.[UserId] = @UserId
|
|
LEFT JOIN
|
|
[dbo].[CollectionUser] CU ON CU.[CollectionId] = C.[Id] AND CU.[OrganizationUserId] = [OU].[Id]
|
|
LEFT JOIN
|
|
[dbo].[GroupUser] GU ON CU.[CollectionId] IS NULL AND GU.[OrganizationUserId] = OU.[Id]
|
|
LEFT JOIN
|
|
[dbo].[Group] G ON G.[Id] = GU.[GroupId]
|
|
LEFT JOIN
|
|
[dbo].[CollectionGroup] CG ON CG.[CollectionId] = C.[Id] AND CG.[GroupId] = GU.[GroupId]
|
|
WHERE
|
|
C.[Id] = @CollectionId
|
|
GROUP BY
|
|
C.[Id],
|
|
C.[OrganizationId],
|
|
C.[Name],
|
|
C.[CreationDate],
|
|
C.[RevisionDate],
|
|
C.[ExternalId]
|
|
|
|
IF (@IncludeAccessRelationships = 1)
|
|
BEGIN
|
|
EXEC [dbo].[CollectionGroup_ReadByCollectionId] @CollectionId
|
|
EXEC [dbo].[CollectionUser_ReadByCollectionId] @CollectionId
|
|
END
|
|
END
|
|
GO
|
|
|
|
CREATE OR ALTER PROCEDURE [dbo].[Collection_ReadByOrganizationIdWithPermissions]
|
|
@OrganizationId UNIQUEIDENTIFIER,
|
|
@UserId UNIQUEIDENTIFIER,
|
|
@IncludeAccessRelationships BIT
|
|
AS
|
|
BEGIN
|
|
SET NOCOUNT ON
|
|
|
|
SELECT
|
|
C.*,
|
|
MIN(CASE
|
|
WHEN
|
|
COALESCE(CU.[ReadOnly], CG.[ReadOnly], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [ReadOnly],
|
|
MIN(CASE
|
|
WHEN
|
|
COALESCE(CU.[HidePasswords], CG.[HidePasswords], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [HidePasswords],
|
|
MAX(CASE
|
|
WHEN
|
|
COALESCE(CU.[Manage], CG.[Manage], 0) = 0
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [Manage],
|
|
MAX(CASE
|
|
WHEN
|
|
CU.[CollectionId] IS NULL AND CG.[CollectionId] IS NULL
|
|
THEN 0
|
|
ELSE 1
|
|
END) AS [Assigned]
|
|
FROM
|
|
[dbo].[CollectionView] C
|
|
LEFT JOIN
|
|
[dbo].[OrganizationUser] OU ON C.[OrganizationId] = OU.[OrganizationId] AND OU.[UserId] = @UserId
|
|
LEFT JOIN
|
|
[dbo].[CollectionUser] CU ON CU.[CollectionId] = C.[Id] AND CU.[OrganizationUserId] = [OU].[Id]
|
|
LEFT JOIN
|
|
[dbo].[GroupUser] GU ON CU.[CollectionId] IS NULL AND GU.[OrganizationUserId] = OU.[Id]
|
|
LEFT JOIN
|
|
[dbo].[Group] G ON G.[Id] = GU.[GroupId]
|
|
LEFT JOIN
|
|
[dbo].[CollectionGroup] CG ON CG.[CollectionId] = C.[Id] AND CG.[GroupId] = GU.[GroupId]
|
|
WHERE
|
|
C.[OrganizationId] = @OrganizationId
|
|
GROUP BY
|
|
C.[Id],
|
|
C.[OrganizationId],
|
|
C.[Name],
|
|
C.[CreationDate],
|
|
C.[RevisionDate],
|
|
C.[ExternalId]
|
|
|
|
IF (@IncludeAccessRelationships = 1)
|
|
BEGIN
|
|
EXEC [dbo].[CollectionGroup_ReadByOrganizationId] @OrganizationId
|
|
EXEC [dbo].[CollectionUser_ReadByOrganizationId] @OrganizationId
|
|
END
|
|
END
|
|
GO
|