dynmap/spigot/build.gradle

description = 'dynmap'

repositories {
    maven {
        url 'https://jitpack.io'
    }
    maven {
        url 'https://repo.codemc.org/repository/maven-snapshots'
    }
}

dependencies {
    compile group: 'org.bukkit', name: 'bukkit', version: '1.7.10-R0.1-SNAPSHOT'
    compile 'com.nijikokun.bukkit:Permissions:3.1.6'
    compile 'me.lucko.luckperms:luckperms-api:4.3'
    compile 'net.luckperms:api:5.0'
    compile('com.github.MilkBowl:VaultAPI:1.7') { transitive = false }
    compileOnly 'net.skinsrestorer:skinsrestorer:14.1.0-SNAPSHOT@jar'
    compile project(":dynmap-api")
    compile project(path: ":DynmapCore", configuration: "shadow")
    compile group: 'ru.tehkode', name: 'PermissionsEx', version: '1.19.1'
    compile group: 'de.bananaco', name: 'bPermissions', version: '2.9.1'
    compile group: 'com.platymuus.bukkit.permissions', name: 'PermissionsBukkit', version: '1.6'
    compile group: 'org.anjocaido', name: 'EssentialsGroupManager', version: '2.10.1'
    compile group: 'org.bstats', name: 'bstats-bukkit', version: '1.5'
    compile group: 'com.googlecode.json-simple', name: 'json-simple', version: '1.1.1'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.2'
    compile project(':bukkit-helper')
    implementation(project(':bukkit-helper-113-2')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-114-1')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-115')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-116')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-116-2')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-116-3')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-116-4')) {
        transitive = false
    }
    implementation(project(':bukkit-helper-117')) {
        transitive = false
    }
}

processResources {
    // replace stuff in mcmod.info, nothing else
    from('src/main/resources') {
        include "plugin.yml"
        // replace version and mcversion
        expand(
                buildnumber: project.parent.ext.globals.buildNumber,
                version: project.version
        )
    }
}

jar {
    classifier = 'unshaded'
}

shadowJar {
    dependencies {
        include(dependency('org.bstats::'))
        include(dependency(':dynmap-api'))
        include(dependency(":DynmapCore"))
        include(dependency(':bukkit-helper'))
        include(dependency(':bukkit-helper-113-2'))
        include(dependency(':bukkit-helper-114-1'))
        include(dependency(':bukkit-helper-115'))
        include(dependency(':bukkit-helper-116'))
        include(dependency(':bukkit-helper-116-2'))
        include(dependency(':bukkit-helper-116-3'))
        include(dependency(':bukkit-helper-116-4'))
        include(dependency(':bukkit-helper-117'))
    }
    relocate('org.bstats', 'org.dynmap.bstats')
    destinationDir = file '../target'
    archiveName = "Dynmap-${parent.version}-spigot.jar"
    classifier = ''
}
shadowJar.doLast {
    task ->
        ant.checksum file: task.archivePath
}

artifacts {
    archives shadowJar
}