buildscript {
    repositories {
        maven { url = 'https://maven.fabricmc.net/' }
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.fabricmc', name: 'fabric-loom', version: '0.10-SNAPSHOT'
    }
}
apply plugin: 'fabric-loom'
loom {
    runConfigs.configureEach {
        ideConfigGenerated = true
    }
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = parent.version
group = parent.group

configurations {
    shadow
    compile.extendsFrom(shadow)
}

dependencies {
    //to change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    compileOnly group: 'com.google.code.findbugs', name: 'jsr305', version: '3.0.2'

    shadow project(path: ':DynmapCore', configuration: 'shadow')
    shadow project(path: ':DynmapCoreAPI', configuration: 'shadow')

    // PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
    // You may need to force-disable transitiveness on them.
}

processResources {
    filesMatching('fabric.mod.json') {
        expand "version": project.version
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    duplicatesStrategy = 'include'
    from "LICENSE"
    from {
        configurations.shadow.collect { it.toString().contains("guava") ? null : it.isDirectory() ? it : zipTree(it) }
    }
}

remapJar {
    archiveName = "${archivesBaseName}-${version}-fabric-${project.minecraft_version}.jar"
    destinationDir = file '../target'
}

remapJar.doLast {
    task ->
        ant.checksum file: task.archivePath
}