mirror of
https://github.com/ViaVersion/ViaVersion.git
synced 2024-11-22 01:55:47 +01:00
60b3ba6bb7
Snakeyaml is an untypical library which most Via platforms don't have and also broke in the past with V2, having it directly in the jar like Gson cleans up the build scripts massively, reduces the build time and also doesn't break in the future if they release V3 or any other breaking changes.
49 lines
1.2 KiB
Plaintext
49 lines
1.2 KiB
Plaintext
enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")
|
|
|
|
dependencyResolutionManagement {
|
|
// configures repositories for all projects
|
|
repositories {
|
|
maven("https://repo.viaversion.com")
|
|
maven("https://repo.papermc.io/repository/maven-public/")
|
|
mavenCentral()
|
|
}
|
|
// only use these repos
|
|
repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
|
|
}
|
|
|
|
pluginManagement {
|
|
// default plugin versions
|
|
plugins {
|
|
id("net.kyori.blossom") version "2.1.0"
|
|
id("org.jetbrains.gradle.plugin.idea-ext") version "1.1.7"
|
|
id("com.github.johnrengelman.shadow") version "8.1.1"
|
|
}
|
|
}
|
|
|
|
rootProject.name = "viaversion-parent"
|
|
|
|
includeBuild("build-logic")
|
|
|
|
setupViaSubproject("api")
|
|
setupViaSubproject("common")
|
|
setupViaSubproject("bukkit")
|
|
setupViaSubproject("bukkit-legacy")
|
|
setupViaSubproject("velocity")
|
|
setupViaSubproject("fabric")
|
|
setupViaSubproject("template")
|
|
|
|
setupSubproject("viaversion") {
|
|
projectDir = file("universal")
|
|
}
|
|
|
|
fun setupViaSubproject(name: String) {
|
|
setupSubproject("viaversion-$name") {
|
|
projectDir = file(name)
|
|
}
|
|
}
|
|
|
|
inline fun setupSubproject(name: String, block: ProjectDescriptor.() -> Unit) {
|
|
include(name)
|
|
project(":$name").apply(block)
|
|
}
|